Can you see a list of all open tabs in Safari?

Question

I often have a good 150 to 200 tabs open in Safari at all times because this is where I like to keep all my current work. Obviously, all open tabs are never displayed at the same time when there are so many...

I am wondering if a list of all currently open tabs is available in Safari.

Answer 1

I don't believe there is a list of tabs available, however, there is a tab overview in Safari if you click

View > Show All Tabs

The keyboard shortcut is Shift+Command+\

Which will show you all of your tabs, grouped by which website they are.

Or if you have pinch-to-zoom support, you can zoom out and it will automatically jump into this view.

Answer 2

Here is an AppleScript that will get the name of all Tabs in all Safari windows and show them in an unsaved TextEdit document.

You can save this as a plain script and access it from the Script menu on the Menu bar if you enable it in Script Editor's Preferences. Or as an App and it can be placed on the Dock.

tell application "Safari"
    set windowCount to number of windows
    set docText to ""
    repeat with x from 1 to windowCount
        set tabcount to number of tabs in window x
        repeat with y from 1 to tabcount
            set tabName to name of tab y of window x
            set docText to docText & tabName & linefeed as string
        end repeat
    end repeat
end tell
tell application "TextEdit"
    activate
    make new document
    set the text of the front document to docText
end tell

The above source code was modified from Generate a List of Open Safari Tabs with AppleScript.

Answer 3

A slight modification to [user3439894][1] AppleScript in order to also get the URL of the tab and save that in the resultant text file.

tell application "Safari"
set windowCount to number of windows
set docText to ""
repeat with x from 1 to windowCount
    set tabcount to number of tabs in window x
    repeat with y from 1 to tabcount
        set tabName to name of tab y of window x
        set theURL to URL of tab y of window x
        set docText to docText & tabName & space & theURL & linefeed as string
    end repeat
end repeat
end tell
tell application "TextEdit"
    activate
    make new document
    set the text of the front document to docText
end tell

Answer 4

You can also use an app called Witch that lets you view a list of Safari Windows and Tabs in a drop down menu, allowing you to choose which one you want.