Applescript: How to get System Events to include subfolders in results?

Question

This is a script that selects a random pdf from a particular folder and reveals it in Finder. But it only selects a pdf from the top level of the folder. How can I get it to look into subfolders as well?

set j to "Macintosh HD:Users:me:Documents:pdfs"

tell application "System Events"
    set all_pdfs to path of every file in folder j whose visible = true and name extension is "pdf"
end tell

set random_pdf to some item of all_pdfs

# uses an existing window or makes a new window with your default settings
tell application "Finder"
    reopen # makes a new window if there are no open windows
    activate
    set target of window 1 to random_pdf
end tell

note: I'm using System Events because it's much faster than Finder.

Answer 1

Here is an alternative method:

Example AppleScript code:

set pdfFilesList to paragraphs of (do shell script "find ~/Documents -type f -iname '*.pdf'")

set pdfFile to POSIX file (some item of pdfFilesList) as alias

tell application "Finder"
    activate
    reveal pdfFile
end tell

Answer 2

Something like this may work for you.

property mainFolder : "Macintosh HD:Users:me:Documents:pdfs"

set theFiles to paragraphs of (do shell script "find " & ¬
    quoted form of POSIX path of mainFolder & " -iname '*.pdf'")
set visiblePDFs to {}

tell application "System Events"
    repeat with thisFile in theFiles
        if visible of file thisFile then set end of visiblePDFs to contents of thisFile
    end repeat
end tell

tell application "Finder"
    reveal some item of visiblePDFs as POSIX file
end tell