Applescript - Close all windows except frontmost window

Question

I have created an automator quick action that runs the following apple script

tell application "System Events"
    set frontApp to name of first application process whose frontmost is true --retrieves name of open application
end tell

tell application frontApp
    repeat while window 2 exists
        close window 2
    end repeat
end tell

It works; however, it takes a while to run if I have a lot of windows open.

Is there a way to close all windows simultaneously except for the frontmost one?

I typed in tell application "Finder" to close every window from 2 to 5 After I compiled it, it automatically changed to tell application "Finder" to close ( windows 2 thru 5 ). However, I get the error message error "Finder got an error: Can’t get windows 2 thru 3." number -1728 from windows 2 thru 3. So, then, it accepts the structure of the command, but I'm still missing something.

Edit: I tried the following script

tell application "Finder"
    close (every window where index is greater than 1)
end tell

However, I get the error "Finder got an error: Handler can’t handle objects of this class." number -10010

Why does this not work?

Answer 1

Please try this. It might run faster. (edited my original answer with new code).

tell application "Finder"

    set theWindows to {}
    set theCount to (count of windows)
    if theCount is greater than 1 then
        repeat with i from 2 to theCount
            set theWindow to window i
            copy theWindow to end of theWindows
        end repeat
        close theWindows
    end if
end tell

Answer 2

If you're running it as an Automator quick action, then you can close all windows except the frontmost window of the frontmost application by using the code below inside a Run AppleScript action (you can delete any sample code that appears, including on run {input, parameters}...end run:

tell application id "com.apple.SystemEvents" to tell the first process ¬
    whose frontmost = true to tell a reference to windows 2 thru -1 to ¬
    if exists then tell the value of attribute "AXCloseButton" to click

Answer 3

I don't expect this to work for every app but it should for any scriptable app. NB Some apps have invisible windows (e.g. omnioutliner has various 'license' windows) so I've added a filtre to only include 'visible' windows. Perhaps that will cause the script to break on some apps. I've tested it on the Finder and OO.

tell application "System Events"
    set frontApp to name of first application process whose frontmost is true
end tell

tell application frontApp
    
    set ab to windows whose visible is true
    set bc to rest of ab
    
    try
        close bc
    on error
        repeat with y in bc
            close y
        end repeat
    end try
    
end tell

In general, the frontmost window has an index of 1. So this script makes a list of visible windows and then uses the 'rest' command to make a second list of every item after the first from list 1 (i.e. not window 1).

Awkwardly, different applications implement 'close' differently. With the Finder you can close a list of windows, with OO you cannot — it generates a -1700 error. So the last part of the script tries to close the list of windows and if that generates an error, it cycles through the list, closing each window sequentially.