Is that possible to make Finder.app to highlight/select newly pasted file(s)?

Question

I am running macOS Big Sur 11.4.

In other operating systems, when you paste new files in file manager, the newly added/pasted files will be highlighted and selected. This is really important and convenient when the current folder/directory has many files. I can find the newly pasted file(s) easily.

But in Finder.app, it doesn't do it. It selects/highlights no file after pasting action.

Is that possible to achieve this in macOS?

I don't want to memorize those filename(s) and find newly pasted file(s) from thousands of files.

Answer 1

You can get the Finder to select newly added files using a Folder Action. First, open Script Editor and add the following code to a new Script window:

on adding folder items to this_folder after receiving added_items
    tell application "Finder"
        select added_items
    end tell
end adding folder items to

Save this script in the folder ~/Library/Scripts/Folder Action Scripts, using whatever name strikes you as convenient (I'll use 'Select Script' for demo purposes).

Second, use spotlight to find and open the Folder Actions Setup app. This is a small helper app hidden way down in the file system (/System/Library/CoreServices) that sets up Folder Actions. You'll see a window that looks something like this:

Use the '+' button on the bottom left to choose a folder you want to attach the action to, then select the desired Folder Action script in the resulting popup menu. The result will look something like this:

Adding items to this folder will now cause the Finder to open a Finder Window and select the added files. Repeat the second step for every folder you want this behavior to occur in. There's no simple way to get the Finder to automatically do this for every folder (it is possible, but it's a PITA).

Answer 2

If you do not mind investing a few minutes, you can open Automator.app and create a new Quick Action document.

Next, add a Run AppleScript command to the workflow and add this following AppleScript code.

activate
set destinationFolder to (choose folder with prompt ¬
    "Choose The Destination Folder" default location ¬
    (path to desktop) with invisibles)

tell application "Finder"
    activate
    set theFiles to selection as alias list
    set duplicatedFiles to duplicate theFiles ¬
        to destinationFolder with replacing and exact copy
    reveal duplicatedFiles
end tell

Next, save your new Automator Quick Action and name it “Reveal Duplicated Files”

Now, anytime you want to duplicate the currently selected files in Finder to another folder then have them revealed snd selected in the new location, just Right Click the Selected files you want to copy and choose Quick Actions/Reveal Duplicated Files. This will open a “Choose Folder” dialog , allowing you to choose the folder where the duplicated files will go. Your files will now be copied to that chosen folder then revealed.

NOTE: The AppleScript code as it is right now, will overwrite any files of the same name, that are currently in the destination folder.