Here is an Applescript that you can save as an Application and access from your dock like any normal application.


----------
**What it does**

It allows you to dynamically change the URL to open if you ned to.

This means you do not have to hard code the URL into the application.

Once a URL is set you just need to click the application at any time in the Dock to open it in FireFox. Or open the App as normal from finder.

You can change the URL easily any time by following step 1 below.


----------


**Step 1, Setting the Apps URL**:

Copy an URL to the clipboard and click the app in the dock.

It will check if the clipboard starts with "http:" if it does it will mean you want to set the url for the app to open in firefox.

A display dialog will open to confirm this and for you to make any adjustments to the URL.

![enter image description here][1]

It will then set the store URL and clear the clipboard.


----------
**Step 2, Opening The URL once an URL has been set:**


Now any time you click the App in the Dock it will open the URL in firefox.


----------


**To change the URL Repeat step 1**.


----------
**The Applescript**

    
    (* stored url *)
    property theUrl : ""
    
    on run
    	
    	(* check if the clipboard has an http url*)
    	set fromClip to the clipboard as string
    	
    	if fromClip starts with "http:" then
    		(* Theclipboard has an http url so this means we want to update the apps url to open in firefox *)
    		
    		(* Confirm this is what we want to do, and we can make adjustments to the url*)
    		display dialog "Set new URL to " default answer fromClip buttons {"Cancel", "OK"} default button 1
    		
    		
    		copy the result as list to {button_pressed, text_returned}
    		if button_pressed is "OK" then
    			(* Set the url to the stored property*)
    			set theUrl to text_returned
    			
    			(* Clear the clipboard*)
    			set the clipboard to ""
    		end if
    		
    		
    	else
    		(* check if the clipboard DID NOT start with http url*)
    		if theUrl is not "" then
    			(* This means   we want to open the current url in firefox *)
    			do shell script "open " & quoted form of theUrl & " -b org.mozilla.firefox"
    		end if
    		
    	end if
    	
    	
    end run


----------
Note:

This is written in OS X 10.9

Where it seems the {text_returned, button_pressed} list is reversed to {button_pressed, text_returned}


  [1]: https://i.sstatic.net/6Xbv8.png