> My question is if there is a keyboard shortcut to open a recently closed preview file?

The following was tested in **macOS Catalina** 10.15.6 and worked for me while **Preview** has focus. (No third-party _applications_ needed.) 

If you just want to open the most recent closed document in **Preview**, then the following _example_ **AppleScript** _code_ used in a **Run AppleScript** _action_ in an **Automator** _Service/Quick Action_ can be assigned a _keyboard shortcut_ in: **System Preferences** > **Keyboard** > **Shortcuts** > **Services** 

- In the **Run AppleScript** _action_ in the **Automator** _Service/Quick Action_, replace the default **AppleScript** _code_ with the following _example_ **AppleScript** _code_:

<!-- language: lang-applescript --> 

	tell application "System Events" to ¬
		click first menu item of ¬
			menu 1 of menu item "Open Recent" of ¬
			menu 1 of menu bar item "File" of ¬
			menu bar 1 of application process "Preview"


[![enter image description here][1]][1]


---

If you want to choose for the Open Recent menu in **Preview**, then the following _example_ **AppleScript** _code_ used in a **Run AppleScript** _action_ in an **Automator** _Service/Quick Action_ _workflow_ can be assigned a _keyboard shortcut_ in: **System Preferences** > **Keyboard** > **Shortcuts** > **Services**

- In the **Run AppleScript** _action_ in the **Automator** _Service/Quick Action_, replace the default **AppleScript** _code_ with the following _example_ **AppleScript** _code_:

<!-- language: lang-applescript --> 

	tell application "System Events" to ¬
		set OpenRecentMenuList to ¬
			get name of menu items of ¬
				menu 1 of menu item "Open Recent" of ¬
				menu 1 of menu bar item "File" of ¬
				menu bar 1 of application process "Preview"

	if the number of items in OpenRecentMenuList is greater than 2 then
		set OpenRecentList to items 1 thru -3 of OpenRecentMenuList
	else
		display dialog "The Open Recent menu is empty." buttons {"OK"} default button 1
		return
	end if

	set menuItem to (choose from list OpenRecentList) as string

	if menuItem is "false" then return

	tell application "System Events" to ¬
		click menu item menuItem of ¬
			menu 1 of menu item "Open Recent" of ¬
			menu 1 of menu bar item "File" of ¬
			menu bar 1 of application process "Preview"


[![enter image description here][2]][2]

---

I assigned the following _keyboard shortcut_ to the **Automator** _Service/Quick Action_ in: **System Preferences** > **Keyboard** > **Shortcuts** > **Services** 

[![enter image description here][3]][3]

---

**Note:** The usual security caveats apply. Permissions will need to be granted as prompted and or required in: **System Preferences** > **Security & Privacy** > **Privacy** > 


  [1]: https://i.sstatic.net/Znj0S.jpg
  [2]: https://i.sstatic.net/wTld2.jpg
  [3]: https://i.sstatic.net/nNmw2.jpg