How to toggle Accessibility features with AppleScript in Ventura

Question

Applescripts for Ventura's new System Settings

My old Applescript stopped working on Ventura. Any ideas on how to fix this script?

tell application "System Preferences"
        reveal anchor "TextToSpeech" of pane id "com.apple.preference.universalaccess"
    end tell
    
    tell application "System Events" to tell process "System Preferences"
        set theCheckbox to checkbox "Speak items under the pointer" of group 1 of window "Accessibility"
        tell theCheckbox
            set checked to true
            click theCheckbox
        end tell
    end tell

Answer 1

This following AppleScript code works for me on macOS Ventura

do shell script "open -b com.apple.systempreferences " & ¬
    "/System/Library/PreferencePanes/UniversalAccessPref.prefPane"

tell application "System Events"
    tell its application process "System Settings"
        repeat until UI element 4 of group 1 of scroll area 1 of group 1 of ¬
            group 2 of splitter group 1 of group 1 of window "Accessibility" exists
            delay 0.1
        end repeat
        click UI element 4 of group 1 of scroll area 1 of group 1 of group 2 ¬
            of splitter group 1 of group 1 of window "Accessibility"
        repeat until checkbox 3 of group 2 of scroll area 1 of group 1 of group ¬
            2 of splitter group 1 of group 1 of window "Spoken Content" exists
            delay 0.1
        end repeat
        click checkbox 3 of group 2 of scroll area 1 of group 1 ¬
            of group 2 of splitter group 1 of group 1 of window "Spoken Content"
    end tell
end tell

tell application "System Settings" to quit

Answer 2

The name of the "System Preferences" app has changed to "System Settings", and the app's UI has changed too.

the "Speak items under the pointer" item is put in "Spoken Content" now.

I am not familiar with AppleScript, but I tried to implement it with JavaScript.

Is this what you expected

#!/usr/bin/env osascript -l JavaScript
// Reveal System Settings
Application("System Settings").reveal()
const settings = Application("System Events").applicationProcesses.byName("System Settings")

// Focus on it
settings.frontmost = true

// Wait for System Settings window appearing
delay(0.5)

// Reveal Accessibility panel
settings.menuBars[0].menuBarItems["View"].menus["View"].menuItems["Accessibility"].click()

// Wait for panel switching
delay(0.5)

// Click Spoken Content
settings.windows[0].groups[0].splitterGroups[0].groups[1].groups[0].scrollAreas[0].groups[0].buttons[3].click()

// check the Speak item under the pointer checkbox
const checkbox = settings.windows[0].groups[0].splitterGroups[0].groups[1].groups[0].scrollAreas[0].groups[1].checkboxes["Speak item under the pointer"]
if (checkbox.value() === 0) {
    checkbox.click()
}

Answer 3

Here is a complete working script.

The previous answer posted on Nov 10, 2022 was not working for me. I don't know why it failed, but Apple might have changed the UI since that date.

This version integrates a corrected reference to the Voice Control checkbox. The reference was provided by Ron Reuter (here). This works for me under macOS Ventura, as of 2023-01-18.

do shell script "open -b com.apple.systempreferences " & ¬
    "/System/Library/PreferencePanes/UniversalAccessPref.prefPane"

tell application "System Events"
    tell its application process "System Settings"
        repeat until UI element 4 of group 1 of scroll area 1 of group 1 of ¬
            group 2 of splitter group 1 of group 1 of window "Accessibility" exists
            delay 0.1
        end repeat
        click UI element 1 of group 3 of scroll area 1 of group 1 of group 2 ¬
            of splitter group 1 of group 1 of window "Accessibility"
        repeat until checkbox "Voice Control" of group 1 of scroll area 1 of group 1 of group 2 of splitter group 1 of group 1 of window "Voice Control" exists
            delay 0.1
        end repeat
        click checkbox "Voice Control" of group 1 of scroll area 1 of group 1 of group 2 of splitter group 1 of group 1 of window "Voice Control"
        
    end tell
end tell

tell application "System Settings" to quit