Automatically apply tag to folder based on content

Question

Is anyone aware of a way to automatically apply a given Finder tag to a folder based on its contents?

For example, I can easily run a Finder search for files based on their "Document Container". But it seems there is no way to get containers based on files they contain. What I'm trying to do is to apply tag "X" to all folders that contain one or more files with file extension "Y". It seems there's no way to do it directly from Finder but I haven't been lucky with Automator either as I can't seem to find a way to select a range of folders based on what they contain.

Answer 1

The proper tool for this job is Hazel.

It can apply tags based on file names, file extensions, even file contents and a lot more. It can also do that on sub-folders as well.

The app has been around for a long time, its developer is very well respected, and the app is well worth its asking price.

There’s a free trial available which you should download and try before buying, but it’s an essential tool for me, and much easier to deal with than Automator and Folder Actions.

Updated To Add

I’m 99% sure that Hazel can do this (if I am understanding the idea properly), and would recommend checking out this page as a starting point:

https://www.noodlesoft.com/manual/hazel/advanced-topics/processing-subfolders/

The developer is also very responsive. The best place to ask questions is here:

https://www.noodlesoft.com/forums/

Answer 2

In Script Editor.app, paste this following AppleScript code into a new document then name and save it as a “scpt” file to /Users/YOUR_SHORT_NAME/Library/Workflows/Applications/Folder Actions folder.

on adding folder items to theFolder after receiving theNewItems
    --  Called after items have been added to a folder
    --  theFolder is a reference to the modified folder
    --  theNewItems is a list of references to the items added to the folder 
    repeat with i from 1 to count of theNewItems
        try
            set thisFile to item i of theNewItems 
            tell application "Finder"
                if name extension of thisFile is "eaf" then
                    set label index of theFolder to 2 -- 2 = Red
                end if
            end tell
        end try
    end repeat
end adding folder items to

(* Anytime Files Are Removed From The Folder That
This Folder Action Is Attached, If None Of The Remaining Files
(If Any) Do Not Have The Name Extension "eaf", The Red Label
Tag Will Be Removed From The Containing Folder *)

on removing folder items from theFolder after losing removedItemNames
    --  Called after items have been removed from a folder
    --  theFolder is a reference to the modified folder
    --  removedItemNames is a list of names of items removed from the folder
    delay 3 -- A Little Buffer If Removed Files Are Large Or Alot
    tell application "Finder"
        set fileRef to a reference to (files of theFolder whose name extension is "eaf")
        if contents of fileRef is {} then
            set label index of theFolder to 0 
        end if
    end tell
end removing folder items from

After your file is saved to that location, you can attach that Folder Action to any folder of your choice by ctrl + click the folder in Finder.app then select “Services” then “Folder Actions Setup…”. From there it’s pretty much self-explanatory. Just attach your new folder actions script to the folder and you should be good to go.

Now anytime a file with the extension “eaf” is added to that folder, the “Red” Finder tag will be added to the folder. On the flip-side, I also added the functionality to monitor the folder when items are removed that if none of the remaining files have the name extension “eaf”, the “Red” Finder tag will be removed from the folder.

---

If you already have a bunch of “eaf” files scattered all over your computer within different folders and you would like to add the “Red” Finder label tag to the containing Folders of those “eaf” files then… In Script Editor.app, paste this following AppleScript code into a new document and run the script.

set containingFolders to {}

set theFiles to paragraphs of ¬
    (do shell script "find ~ -type f -iname '*.eaf'") as list
    
tell application "Finder"
    repeat with i from 1 to count of theFiles
        set thisItem to item i of theFiles
        set aContainer to container of ¬
            (thisItem as POSIX file as alias) as alias
        if aContainer is not in containingFolders then ¬
            set end of containingFolders to aContainer
    end repeat
    repeat with thisContainer in containingFolders
        set label index of thisContainer to 2
    end repeat
end tell