How do I get Automator actions for Microsoft Powerpoint and Word?

Question

I'm trying to set up Automator with a folder action to convert any Powerpoint or Word documents I drag into it to PDFs.

I found this question: How do I script Powerpoint to save a directory of PPTX files as PDFs?, but I don't have any Automator actions for Powerpoint or Word.

Here's what I see in Automator.

When I search in actions for "convert", here's what I get.

• Mac OS 10.10.5
• Powerpoint version 15.15
• Word version 15.15

Answer 1

Microsoft Office for Mac 2011 (and 2008) includes several Automator workflows, but Microsoft is no longer providing Automator actions for Office 2016.

So, you must run an AppleScript from the Automator workflow

Here is the script (edited):

on run {input, parameters}
    set theOutput to {}
    tell application "Microsoft PowerPoint" -- work on version 15.15 or newer
        launch
        set theDial to start up dialog
        set start up dialog to false
        repeat with i in input
            open i
            set pdfPath to my makeNewPath(i)
            save active presentation in pdfPath as save as PDF -- save in same folder
            close active presentation saving no
            set end of theOutput to pdfPath as alias
        end repeat
        set start up dialog to theDial
    end tell
    return theOutput
end run

on makeNewPath(f)
    set t to f as string
    if t ends with ".pptx" then
        return (text 1 thru -5 of t) & "pdf"
    else
        return t & ".pdf"
    end if
end makeNewPath

This script return path of the PDF files to the next action.

---

Here is the workflow:

Answer 2

Do you have the full version of Microsoft Office installed?
The Automator actions are part of Office & added when Office is installed.
Microsoft Office Home and Student Edition does not have Automator Actions

Also see : Office applications missing in Automator Library

The mention on there of Viewing by Application or Category doesn't appear to prevent them showing in the search, only in the left pane