1

The AppleScript code:

on dialogBox(theMessage)
display dialog theMessage default answer "" buttons {"Cancel", "Search"} default button 2 with title "Pick a search engine"
end dialogBox

dialogBox("Google, YouTube, Wiki, Dictionary, Apple, Adobe, or Google Images")

if text returned of result = "Google" then
set search to text returned of dialogBox("Enter Google Search")
tell application "Google Chrome"
    activate
    open location "https://www.google.com/?gfe_rd=cr&ei=4fJgVJ6SM8yD8QfJjYGICA&gws_rd=ssl,cr&fg=1#q=" & search
end tell

else if text returned of result = "YouTube" then
set search to text returned of dialogBox("Enter YouTube Search")
tell application "Google Chrome"
    activate
    open location "https://www.youtube.com/results?search_query=" & search


end tell


else if text returned of result = "Wiki" then
set search to text returned of dialogBox("Enter Word")
tell application "Google Chrome"
    activate
    open location "http://en.wikipedia.org/wiki/" & search


end tell

else if text returned of result = "Dictionary" then
set search to text returned of dialogBox("Enter Word")
tell application "Google Chrome"
    activate
    open location "http://Dictionary.Reference.Com/Browse/" & search


end tell

else if text returned of result = "Apple" then
set search to text returned of dialogBox("Enter Apple Search")
tell application "Google Chrome"
    activate
    open location "http://www.apple.com/search/?q=" & search


end tell

else if text returned of result = "Adobe" then
set search to text returned of dialogBox("Enter Adobe Search")
tell application "Google Chrome"
    activate
    open location "http://www.adobe.com/cfusion/search/index.cfm?term=" & search

end tell

else if text returned of result = "Google Images" then
set search to text returned of dialogBox("Enter Image Search")
tell application "Google Chrome"
    activate
    open location "https://www.google.ca/search?site=imghp&tbm=isch&source=hp&biw=1920&bih=890&q=" & search

end tell
end if

The Problem:

At the top, it says ("Google, YouTube, Wiki, Dictionary, Apple, Adobe, or Google Images")

I want to make it so it puts a question mark at the end, like so: ("Google, YouTube, Wiki, Dictionary, Apple, Adobe, or Google Images?")

The Google Images has a question mark but when I type "Google Images" in the text box, it closes. Can someone help so I can type Google Images with the question mark and the program doesn't close?

0

Add "Google Images?" to the acceptable results for the text returned.

else if text returned of result is in {"Google Images", "Google Images?"} then

instead of:

else if text returned of result = "Google Images" then

This will allow for you to enter both as acceptable answers in your dialog.

|improve this answer|||||
0

I would recommend you change your script to something like this, to avoid all the copy/pasting:

-- this makes it much easier to add a new search engine. The '¬' means the line is continued on the next line.
set searchEngines to { ¬
    {name:"Google", URL:"https://www.google.com/?q="}, ¬
    {name:"YouTube", URL:"https://www.youtube.com/results?search_query="}, ¬
    {name:"Wikipedia", URL:"https://en.wikipedia.org/w/index.php?title=Special%3ASearch&go=Go&search="}, ¬
    {name:"Dictionary", URL:"http://dictionary.reference.com/browse/"}, ¬
    {name:"Apple", URL:"http://www.apple.com/search/?q="}, ¬
    {name:"Adobe", URL:"http://www.adobe.com/cfusion/search/index.cfm?term="}, ¬
    {name:"Images", URL:"https://www.google.ca/search?site=imghp&tbm=isch&source=hp&biw=1920&bih=890&q="} ¬
}

set names to {}
repeat with searchEngine in searchEngines
    set end of names to name of searchEngine
end repeat
choose from list names with prompt "Select a search engine"
if result is false then -- you hit Cancel
    return
else
    set searchEngineName to item 1 of result
end if
repeat with searchEngine in searchEngines
    if name of searchEngine is searchEngineName then
        display dialog "Search " & searchEngineName & ":" buttons {"Cancel", "Search"} default button 2 default answer ""
        open location (URL of searchEngine & text returned of result)
    end if
end repeat
|improve this answer|||||

You must log in to answer this question.

Not the answer you're looking for? Browse other questions tagged .