Positioning desktop icons on the left instead of right

Question

Any way to automatically make alias or icons to show up on the left side of apple desktop. By default they go to the right.

Answer 1

There is no way to force icons to go to the left automatically (and stay arranged by the criterion you choose).

As a workaround, you can change the View Options in Finder to not arrange items by any criterion and place icons manually on the left.

• Click on an empty space on the desktop.
• Press Cmd+J or use the mouse to go to the Finder's View > Show View Options menu.
• In the Sort by: dropdown in the dialog, choose either None or Snap to Grid.
• You'll be able to drop files anywhere on your desktop and they'll stay there.

See Mac Basics: Modify your windows for more information.

Also go through the Mac Basics pages to learn more about using a Mac.

Answer 2

This is not the best solution but it can work if nothing else does...

1. Create an Automator Folder Action associated with the Desktop.
2. Add the item: "run applescript"

3. Paste the following code in the applescript text box:

   -- https://gist.github.com/mrienstra/8330528
   -- Based on http://www.tuaw.com/2012/12/24/applescript-desktop-icon-race/
   -- Inspired by http://namesakecomic.com/comic/happy-new-year-from-namesake/#comment-1182035013
   
   -- Rearranges Desktop icons to flow from left to right, top to bottom.
   
   -- To have this run automatically every time files are added or removed from the Desktop, set this script to run as a Desktop "Folder Action". (See https://developer.apple.com/library/mac/documentation/applescript/conceptual/applescriptlangguide/reference/ASLR_folder_actions.html )
   
   -- This is currently a rough proof-of-concept. It has only been tested with OS X 10.8.5 (Mountain Lion).
   
   -- Current known limitations: Does not work with "Label position" set to "Right" (specifically, icons will overlap).
   
   
   
   -- Adjust these for different spacing
   property theSpacingFactor : 1.0
   property theGutterXFactor : 0.57
   property theGutterYFactor : 0.57
   
   
   
   on rearrangeDesktopIcons()
       tell application "Finder"
           tell icon view options of window of desktop
               set theArrangement to arrangement
               set theArrangementString to theArrangement as string
               if {"not arranged", "«constant ****narr»", "snap to grid", "«constant ****grda»"} does not contain theArrangementString then
                   display alert "\"Rearrange Desktop Icons\" AppleScript says:" message "Cannot rearrange Desktop items, please change Desktop \"Sort by\" to \"None\" or \"Snap to Grid\"." giving up after 10
                   return
               end if
               set theIconSize to icon size
               set theLabelSize to text size
           end tell
   
           set theDesktopBounds to bounds of window of desktop
           set theDesktopWidth to item 3 of theDesktopBounds
           set theDesktopHeight to item 4 of theDesktopBounds
   
           -- Retrieve a list of items on the desktop
           set theDesktopItems to every item of desktop
           set theContestantOffset to theIconSize / 2
   
           set theSpacing to (theIconSize + theLabelSize + theContestantOffset) * theSpacingFactor
           set theGuttersX to theSpacing * theGutterXFactor
           set theGuttersY to theSpacing * theGutterYFactor
           set theMaxColumns to ((theDesktopWidth - theGuttersX * 2) / theSpacing) as integer
           set theMaxRows to ((theDesktopHeight - theGuttersY * 2) / theSpacing) as integer
           set theMaxLocations to theMaxRows * theMaxColumns
   
           set y to 1
           repeat with a from 1 to length of theDesktopItems
               set x to a mod theMaxColumns
               if x is 0 then
                   set x to theMaxColumns
               end if
   
               if a is greater than theMaxLocations then
                   set desktop position of item a of theDesktopItems to {theGuttersX, theGuttersY}
               else
                   set desktop position of item a of theDesktopItems to {theGuttersX + (x - 1) * theSpacing, theGuttersY + (y - 1) * theSpacing}
               end if
   
               if a mod theMaxColumns is 0 then
                   set y to y + 1
               end if
           end repeat
       end tell
   end rearrangeDesktopIcons
   
   
   
   on adding folder items to alias after receiving listOfAlias
       rearrangeDesktopIcons()
   end adding folder items to
   
   on removing folder items from alias after losing listOfAliasOrText
       rearrangeDesktopIcons()
   end removing folder items from
   
   rearrangeDesktopIcons()
   

So whenever a file is added to your Desktop, all files will be rearranged alphabetically...

Answer 3

Organize all the folders in the order you want them. Then under View hit 'clean up.' This will align everything nicely. Then you can simply highlight all of the folders and position them exactly where you want them. Macs don't organize folders on the left, only the right, but with a couple of easy steps you can have everything neatly organized on the left.

Answer 4

I just highlighted all the folders from the right hand side, then grabbed them all and pasted to the left.