Take the 2-minute tour ×
Ask Different is a question and answer site for power users of Apple hardware and software. It's 100% free, no registration required.

I want to export specific address book groups to mailchimp from a clients Mac computer.

The client have version OS X Lion (10.7) and the Mac she has is faulty and will be scrapped soon. Therefore it is not feasible to upgrade it.

It would be perfect if I could use Chimport but it appears that I need OS X Mountain Lion to use Apple Mac Store to get it.

Alternative do you know any programs that can export to CSV?

share|improve this question
    
The Apple Store is working for OS X Lion as well (if that's really the OS version on your client's computer) –  patrix Nov 1 '12 at 14:28
    
I will need to double check the version. Somehow I could not use Apple Mac Store –  Cudos Nov 1 '12 at 14:58
    
Does this answer your question? apple.stackexchange.com/questions/66520/… –  timothymh Nov 2 '12 at 2:34
add comment

2 Answers

up vote 0 down vote accepted

The following AppleScript will export all the names and e-mail addresses from Contacts.app. It was written for OS X 10.9 but should work on older editions; you may need to change Contacts to Address Book to talk to the appropriate application:

To use this AppleScript:

  1. Launch AppleScript Editor from Applications > Utilities
  2. Copy and paste the code below into a new document
  3. Run the script
  4. On completion a contacts.csv will appear on your desktop

Export Contacts to CSV AppleScript

-- Save comma separated values (CSV) file to desktop
set exportPath to (path to desktop as string) & "contacts.csv"

set contactsCSV to "" -- variable to collect rows of addresses
set quoteString to "\"" -- constant to ease concatenation

tell application "Contacts"

    -- Repeat with every person in your Contacts
    repeat with x from 1 to the count of people
        set thePerson to person x
        set theirName to the name of thePerson

        -- A person may have multiple e-mails addresses, add one row for each
        repeat with anEmail in the email of thePerson
            set contactsCSV to contactsCSV & quoteString & theirName & quoteString & "," & quoteString & (value of anEmail) & quoteString & "
"
        end repeat
    end repeat

end tell

-- Write the CSV contents to a file
set exportFile to open for access file exportPath with write permission
set eof of exportFile to 0
write contactsCSV to exportFile starting at eof
close access exportFile
share|improve this answer
add comment

Export your contacts as a VCARD bundle from Contacts.app and then import them into a account which supports the VCARD format. Once in Gmail, you can then export them as a file.

share|improve this answer
add comment

Your Answer

 
discard

By posting your answer, you agree to the privacy policy and terms of service.

Not the answer you're looking for? Browse other questions tagged or ask your own question.